File Manager

X7ROOT File Manager

Current Path: /etc/profile.d

📁 ..
📄 bash_timestamps.sh(69 B)
📄 colorgrep.csh(196 B)
📄 colorgrep.sh(201 B)
📄 colorls.csh(1.7 KB)
📄 colorls.sh(1.57 KB)
📄 colorsysstat.csh(69 B)
📄 colorsysstat.sh(56 B)
📄 colorxzgrep.csh(162 B)
📄 colorxzgrep.sh(183 B)
📄 colorzgrep.csh(216 B)
📄 colorzgrep.sh(220 B)
📄 cpanel-php-composer.sh(548 B)
📄 cpanel-user-commands.sh(513 B)
📄 csh.local(80 B)
📄 debuginfod.csh(674 B)
📄 debuginfod.sh(596 B)
📄 gawk.csh(1.08 KB)
📄 gawk.sh(757 B)
📄 lang.csh(2.43 KB)
📄 lang.sh(2.26 KB)
📄 less.csh(500 B)
📄 less.sh(253 B)
📄 locallib.csh(240 B)
📄 locallib.sh(288 B)
📄 mc.csh(49 B)
📄 mc.sh(153 B)
📄 modules.csh(105 B)
📄 modules.sh(448 B)
📄 prompt.sh(2.11 KB)
📄 puppet-agent.csh(91 B)
📄 puppet-agent.sh(373 B)
📄 scl-init.csh(284 B)
📄 scl-init.sh(637 B)
📄 sh.local(81 B)
📄 vim.csh(106 B)
📄 vim.sh(248 B)
📄 which2.csh(120 B)
📄 which2.sh(540 B)

Editing: colorls.csh

# skip everything for non-interactive shells
if (! $?prompt) exit

# color-ls initialization
if ( $?USER_LS_COLORS ) then
  if ( "$USER_LS_COLORS" != "" ) then
     #when USER_LS_COLORS defined do not override user
     #specified LS_COLORS and use them
     goto finish
  endif
endif

alias ll 'ls -l'
alias l. 'ls -d .*'
set COLORS=/etc/DIR_COLORS

if ($?TERM) then
  if ( -e "/etc/DIR_COLORS.256color" ) then
    if ( "`/usr/bin/tput colors`" == "256" ) then
       set COLORS=/etc/DIR_COLORS.256color
    endif
  endif
  if ( -e "/etc/DIR_COLORS.$TERM" ) then
     set COLORS="/etc/DIR_COLORS.$TERM"
  endif
endif
if ( -f ~/.dircolors ) set COLORS=~/.dircolors
if ( -f ~/.dir_colors ) set COLORS=~/.dir_colors
if ($?TERM) then
  if ( -f ~/.dircolors."$TERM" ) set COLORS=~/.dircolors."$TERM"
  if ( -f ~/.dir_colors."$TERM" ) set COLORS=~/.dir_colors."$TERM"
endif
set INCLUDE="`/usr/bin/cat "$COLORS" | /usr/bin/grep '^INCLUDE' | /usr/bin/cut -d ' ' -f2-`"

if ( ! -e "$COLORS" ) exit

set _tmp="`/usr/bin/mktemp .colorlsXXX -q --tmpdir=/tmp`"
#if mktemp fails, exit when include was active, otherwise use $COLORS file
if ( "$_tmp" == '' ) then
  if ( "$INCLUDE" == '' ) then
    eval "`/usr/bin/dircolors -c $COLORS`"
  endif
  goto cleanup
endif

if ( "$INCLUDE" != '' ) /usr/bin/cat "$INCLUDE" >> $_tmp
/usr/bin/grep -v '^INCLUDE' "$COLORS" >> $_tmp

eval "`/usr/bin/dircolors -c $_tmp`"

/usr/bin/rm -f $_tmp

if ( "$LS_COLORS" == '' ) exit
cleanup:
set color_none=`/usr/bin/sed -n '/^COLOR.*none/Ip' < $COLORS`
if ( "$color_none" != '' ) then
   unset color_none
   exit
endif
unset color_none
unset _tmp
unset INCLUDE
unset COLORS

finish:
alias ll 'ls -l --color=auto'
alias l. 'ls -d .* --color=auto'
alias ls 'ls --color=auto'

X7ROOT File Manager

Editing: colorls.csh

Upload File

Create Folder